Recess At Last — 6 of 73

of thing. A jotter has a list of indexed text called the missive. A jotter can be fresh or marked. A jotter is usually fresh.

A scriber is a kind of thing.

After reading a command:

remove quotes;

resolve punctuated titles.

[This will allow the player to type optional quotation marks around the text to be written without also recording the quotes. It will also strip the period out if the player types "Mrs." or "Mr."]

Instead of reading a jotter (called the pad):

if the pad is a packet:

say "On [the pad] is printed:[/p][prompt of the pad].";

otherwise:

say "On [the pad] you read:[/p][the missive of the pad vertically]".

Instead of examining a fresh jotter (called the pad):

if the pad is a packet, say "[description of pad][/p]On [the pad] is printed:[/p][prompt of the pad]. There is nothing written in the blanks.";

otherwise say "[description of pad] [if the pad is not the jeans]There is nothing written on it.[end if]"

Instead of examining a marked jotter (called the pad):

if the pad is a packet:

say "[description of pad][/l]On [the pad] is printed:[/l][prompt of the pad].";

if the pad is completed, say "It appears to be complete and ready to hand in.";

if the pad is the assignment:

now the printed name of the assignment is "finished Explorer assignment";

now the description of the assignment is "This is the Explorer worksheet you finished yesterday.";

otherwise:

say "[description of pad][/l]On [the pad] you read:[/l][the missive of the pad vertically]".

To say (chosen list - a list of indexed text) vertically:

repeat with current entry running through chosen list:

say "[current entry][/l]".

To erase (pad - a jotter):

truncate the missive of the pad to zero entries;

now the pad is fresh;

To write on (pad - a jotter):

let N be indexed text;

let N be "[topic understood]" in sentence case;

add N to the missive of the pad;

now the pad is marked.

Understand "write [text] on [something touchable]" as writing it on. Understand "write [text]" as writing it on. Understand "write down" as "[write]".

Writing it on is an action applying to one topic and one thing.

Rule for supplying a missing second noun while writing:

if a jotter (called the pad) is carried:

change the second noun to the pad;

otherwise if a jotter (called the pad) is touchable:

change the second noun to the pad;

otherwise:

say "You will have to specify what to write that on.".

Definition: a thing is writable:

if it is a jotter then decide yes;

if it is your chair then decide yes;

decide no.

Does the player mean doing something when the second noun is the blue jeans: it is very unlikely.

Check writing it on:

if the player does not hold a scriber, say "You have nothing to write with." instead;

if the second noun is not writable, say "You really shouldn[']t write anything there." instead;

if the second noun is a packet, say "If you want to fill in the answers to the questions, try 'COMPLETE QUESTION 1'." instead;

if the player holds a packet, say "If you are trying to fill in the answers on the worksheet, use the command 'COMPLETE QUESTION 1' instead.".

Carry out writing it on:

if the second noun is your chair

begin;

now the description of your chair is "You can tell this is your chair because of the design you scribbled onto the seat.";

move the design to Room 9;

now the description of the design is "Just a little random picture you drew in pencil when you were bored during recess today. It doesn[']t even look like anything specific.";

otherwise;

write on the second noun;

end if.

Report writing it on:

if the second noun is your chair, say "You scribble another random design on it, just like the one you drew last week in math class.";

say "In your best cursive handwriting, you write '[topic understood in sentence case]' on [the second noun]."

Erasing is an action applying to one carried thing. Understand "erase [something touchable]" as erasing.

Check erasing:

if the player does not hold a scriber, say "You have nothing to erase it with." instead;

if the noun is not a jotter or the second noun is not your chair, say "It's hard to see how." instead.

Carry out erasing:

if the noun is your chair

begin;

now the description of your chair is "Nothing special, really. Blue plastic seat, metal legs. Good for making static and shocking people in the winter, though.";

remove the design from play;

otherwise;

erase the noun;

end if.

Report erasing:

say "You scrub [the noun] with your eraser until all the pencil marks are gone."

To error-correct (pad - a jotter):

let N be indexed text;

let N be "[topic understood]" in sentence case;

repeat with current entry running through the missive of the pad

begin;

if current entry matches the text N, remove current entry from the missive of the pad;

end repeat.

Erasing it from is an action applying to one topic and one carried thing. Understand "erase [text] on/in/from [something touchable]" as erasing it from.

Check erasing it from:

if the player does not hold a scriber, say "You have nothing to erase it with." instead;

if the second noun is your chair, try erasing your chair instead;

if the second noun is not a jotter, say "It's hard to see how." instead;

let N be indexed text;

let N be "[topic understood]" in sentence case;

if N is not listed in the missive of the second noun, say "You scan [the second noun], but cannot see '[N]' written anywhere on it." instead.

Carry out erasing it from:

error-correct the second noun.

Report erasing it from:

say "You carefully erase every line containing '[topic understood in sentence case]' from the page, leaving all the other writing."

Copying is an action applying to two things. Understand "copy [something preferably held] on [something touchable]" as copying. Understand "copy [something preferably held]" as copying.

Rule for supplying a missing second noun while copying when the noun is a packet:

if a packet (called the pad) is carried

begin;

change the second noun to the pad;

otherwise if a packet (called the pad) is touchable;

change the second noun to the pad;

otherwise;

say "You will have to specify what to write that on.";

end if.

Rule for supplying a missing second noun while copying:

if a jotter (called the pad) is carried:

change the second noun to the pad;

otherwise if a jotter (called the pad) is touchable:

change the second noun to the pad;

otherwise:

say "You will have to specify what to write that on.".

Check copying:

if the player does not hold a scriber, say "You have nothing to write with." instead;

if the noun is not a jotter or the noun is fresh, say "There's nothing written on this for you to copy." instead;

if the noun is a packet and a fresh packet is not held, say "You need a blank copy of the worksheet to copy the answers onto." instead;

if a fresh jotter is not held, say "You need a clean sheet to write on" instead.

Carry out copying:

if the noun is a packet, let the target be a random fresh packet held by the player;

otherwise let the target be a random fresh jotter held by the player;

repeat with current entry running through the missive of the noun

begin;

add current entry to the missive of the target;

end repeat;

now the target is marked.

Report copying:

say "You carefully copy the writing from [the noun] and make a duplicate."

Part 5 - Packets